PD ROM 1/PD ROM Volume I - Macintosh Software from BMUG (1988).iso/Programming/Programming Tools/Modula 2-menus/Sample.MOD

Text File | 1987-06-11 | 5.6 KB | 167 lines | [TEXT/ttxt]

(*$T+,$F+*)

(*-------------------------------------------------------------*)
(*                    >>> SAMPLE PROGRAM <<<                   *)
(*-------------------------------------------------------------*)
(*                                                             *)
(*  This is an example program which shows just how EASY it    *)
(*  is to set up your own menu system by using EasyMenus.     *)
(*                                                             *)
(*  J.A. Pillera, June 1987                                    *)
(*-------------------------------------------------------------*)

MODULE Sample;


FROM EasyMenus IMPORT AppendToMenu, CheckMenuItem, CreateMenu,
                      HandleDA, HandleEdit, Line, MenuEnableStatus,
                      MenuItemStyle, NoKey, SetItemEnable,
                      SetMenuEnable, SetUpFontMenu, UpdateMenuBar,
                      UserEvent;

FROM InOut IMPORT WriteString, WriteInt, WriteLn;

VAR
 (* Sample-program varaibles *)
 MenuItem, MenuBar, LastChecked : INTEGER;
 InDA : BOOLEAN;

(* Use my EASY function calls to set up an elaborate menu! *)
PROCEDURE MakeMyMenus;

  BEGIN (* MakeMyMenus *)
    (* NOTE: The Desk Accessory Menu takes the ID #1! *)
    (* File Menu *)
    CreateMenu(2,"File");
    AppendToMenu(2,"New",NoKey,normal);
    AppendToMenu(2,"Open",'O',normal);
    AppendToMenu(2,"Close",NoKey,normal);
    AppendToMenu(2,"Save",'S',normal);
    AppendToMenu(2,"Print",'P',normal);
    AppendToMenu(2,Line,NoKey,normal);
    AppendToMenu(2,"Enable  Status Menu",NoKey,normal);
    AppendToMenu(2,"Disable Status Menu",NoKey,normal);
    AppendToMenu(2,Line,NoKey,normal);
    AppendToMenu(2,"Quit",'Q',normal);

    (* APPEND to edit menu *)
    AppendToMenu(3,Line,NoKey,normal);
    AppendToMenu(3,"Select All",NoKey,normal);

    (* Format Menu *)
    CreateMenu(4,"Format");
    AppendToMenu(4,"Normal",NoKey,normal);
    AppendToMenu(4,"Bold",NoKey,bold);
    AppendToMenu(4,"Italic",NoKey,italic);
    AppendToMenu(4,"Underline",NoKey,underline);
    AppendToMenu(4,"Outline",NoKey,outline);
    AppendToMenu(4,"Shadow",NoKey,shadow);

    (* Set up the Font Menu! *)
    SetUpFontMenu;

    (* Special Menu *)
    CreateMenu(6,"Special");
    AppendToMenu(6,"Enabled",'E',normal);
    AppendToMenu(6,"Disabled",'D',normal);
    SetItemEnable(6,2,disabled);
    AppendToMenu(6,Line,NoKey,normal);
    AppendToMenu(6,"Checked",NoKey,normal);
    CheckMenuItem(6,4,TRUE);
    AppendToMenu(6,"Unchecked",NoKey,normal);

    (* Disabled/Enabled Menu *)
    CreateMenu(7,"Status");
    AppendToMenu(7,"Menu Item 1",NoKey,normal);
    AppendToMenu(7,"Menu Item 2",NoKey,normal);
    AppendToMenu(7,"Menu Item 3",NoKey,normal);
    AppendToMenu(7,"Menu Item 4",NoKey,normal);
    AppendToMenu(7,Line,NoKey,normal);
    AppendToMenu(7,"Menu Item 5",NoKey,normal);
    AppendToMenu(7,"Menu Item 6",NoKey,normal);

    (* Now kill the Status Menu *)
    SetMenuEnable(7,disabled);

    (* Draw the menu bar *)
    UpdateMenuBar;
  END MakeMyMenus;

BEGIN (* Main *)
  (* This is a sample main program to show how easy it is to *)
  (* use EasyMenus  in your application.                     *)
  MakeMyMenus;
  LastChecked := 0; (* For playing around with the Font Menu *)
  (* Suppress output while in a DA! *)
  InDA := FALSE;
  (* Test the menu system *)
  WriteLn;
  WriteString("Entering menu test . . .");
  WriteLn; WriteLn;
  LOOP

   (* See if the user selected a menu item with the mouse or *)
   (* by using the Command Key.  If so, process the request. *)
   IF UserEvent(MenuBar,MenuItem) THEN

     (* Disable output while in DAs *)
     IF MenuBar > 1 THEN
       InDA := FALSE;
     END;

     (* Output where the mouse-down or key-down occured *)
     IF NOT(InDA) THEN
       WriteLn;
       WriteString("Menu Bar  = "); WriteInt(MenuBar,3); WriteLn;
       WriteString("Menu Item = "); WriteInt(MenuItem,3); WriteLn;
     END;

     (* Handle a Desk Accessory event.                        *)
     (* NOTE!  This is for illustrative purposes only.  To do *)
     (*        a good job, you should disable your menu items *)
     (*        that don't apply for desk accessories.  This   *)
     (*        is why I notify you of a DA event before       *)
     (*        processing it!                                 *)
     IF MenuBar = 1 THEN
       InDA := TRUE;
       HandleDA(MenuItem);
     END;

     (* These IF statements show how to enable/disable menus! *)
     (* Enable or Disable the Status Menu *)
     IF (MenuBar = 2) AND (MenuItem = 7) THEN
       WriteString("Enabling the Status Menu!"); WriteLn;
       SetMenuEnable(7,enabled);
     END;
     IF (MenuBar = 2) AND (MenuItem = 8) THEN
       WriteString("Disabling the Status Menu!"); WriteLn;
       SetMenuEnable(7,disabled);
     END;

     (* These IF statements play around with check marks *)
     (* in the Font Menu!                                *)
     IF MenuBar = 5 THEN
       (* Do we have a previous item to uncheck? *)
       IF LastChecked = 0 THEN
         (* This is the very first check mark *)
         CheckMenuItem(MenuBar,MenuItem,TRUE);
         LastChecked := MenuItem;
       ELSE
         (* Uncheck the previous check first!      *)
         CheckMenuItem(MenuBar,LastChecked,FALSE);
         (* Now place a check next to the new item *)
         CheckMenuItem(MenuBar,MenuItem,TRUE);
         LastChecked := MenuItem;
       END;
     END;

     (* See if quit was selected! *)
     IF (MenuBar = 2) AND (MenuItem = 10) THEN
       WriteLn; WriteString("Bye Bye!");
       EXIT;
     END;
    END;
  END;
END Sample.